#암기은행 for MDict TTS 실행
#2009. 4. 15  by 곤이. mymits.net

#MDict ver 3.0 RC1 or Final
#SendCommand("MDict",32883)  가 클립보드 문자열 백그라운드 검색
#SendCommand("MDict",1037)   가 소리 다시재생

#반복횟수
rpN = 2
#암기은행 실행파일 위치
MBFile = "\Program Files\MemoBank\MemoBank.exe"
#MDict 실행파일 위치
MDFile = "\Storage Card\Program Files\Octopus Studio\MDict\MDict.exe"

#반복듣기 속도(숫자가 크면 늦게 반복됨 단위:ms)
rDelay = 500
#한번 실행 후 잠시쉬기, 숫자가 작으면 cpu점유율 올라감
sleepDelay = 300


modeIn = -1
modeIn = Question("반복 듣기 하시겠습니까?", "암기은행 음성듣기",  "YesNoCancel" )

While (modeIn < 0)
	Sleep(600)
EndWhile

#실행전 화면꺼짐 시간저장
BattSuspendTimeout = RegRead ("HKLM", "System\CurrentControlSet\Control\Power\Timeouts","BattSuspendTimeout")
ACSuspendTimeout = RegRead ("HKLM", "System\CurrentControlSet\Control\Power\Timeouts","ACSuspendTimeout")
BatteryTimeout = RegRead ("HKCU", "ControlPanel\Backlight", "BatteryTimeout")
ACTimeout = RegRead ("HKCU", "ControlPanel\Backlight", "ACTimeout")

#항상 켜진상태 유지
RegWriteDword ("HKLM", "System\CurrentControlSet\Control\Power\Timeouts","BattSuspendTimeout",0)
RegWriteDword ("HKLM", "System\CurrentControlSet\Control\Power\Timeouts","ACSuspendTimeout",0)
RegWriteDword ("HKCU", "ControlPanel\Backlight", "BatteryTimeout", 0)
RegWriteDword ("HKCU", "ControlPanel\Backlight", "ACTimeout", 0)

Run(MDFile)
WaitFor("MDict",8)

Run(MBFile)
WaitFor("암기은행",8)
Show("암기은행")

ClipT = ""

While ( WndExists("MDict") AND WndExists("암기은행") AND (modeIn < 2))
	tmp = ClipText()
	If(ClipT ne tmp)
	ClipT = tmp
		#MDict에 메세지 보내기.
		SendCommand("MDict",32883)
		rpNTemp = 1
		While ( (rpNTemp < rpN) AND modeIn AND ((ClipT eq ClipText()) AND WndExists("MDict") AND WndExists("암기은행")  AND WndActive("암기은행") ) )
			Sleep(rDelay)
			#음성듣기
			SendCommand("MDict",1037)
			rpNTemp = rpNTemp + 1
		EndWhile
	EndIf
	Sleep(sleepDelay)
EndWhile
#실행전 화면꺼짐 시간복구
RegWriteDword ("HKLM", "System\CurrentControlSet\Control\Power\Timeouts","BattSuspendTimeout",BattSuspendTimeout)
RegWriteDword ("HKLM", "System\CurrentControlSet\Control\Power\Timeouts","ACSuspendTimeout",ACSuspendTimeout)
RegWriteDword ("HKCU", "ControlPanel\Backlight", "BatteryTimeout", BatteryTimeout)
RegWriteDword ("HKCU", "ControlPanel\Backlight", "ACTimeout", ACTimeout)

Exit